diff --git a/dev-vcs/gitlab-shell/gitlab-shell-3.6.1.ebuild b/dev-vcs/gitlab-shell/gitlab-shell-3.6.1.ebuild
new file mode 100644
index 0000000..f9f7f1e
--- /dev/null
+++ b/dev-vcs/gitlab-shell/gitlab-shell-3.6.1.ebuild
@@ -0,0 +1,130 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+USE_RUBY="ruby21 ruby23"
+
+inherit eutils ruby-ng user
+
+MY_PV="v${PV/_/-}"
+MY_GIT_COMMIT="b71ca5da9fde4fa8457af146bd090ec7caa28d60"
+
+DESCRIPTION="SSH access and repository management for GitLab"
+HOMEPAGE="https://gitlab.com/gitlab-org/gitlab-shell"
+SRC_URI="https://gitlab.com/gitlab-org/gitlab-shell/repository/archive.tar.gz?ref=${MY_PV} -> ${P}.tar.gz"
+RUBY_S="${PN}-${MY_PV}-${MY_GIT_COMMIT}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+IUSE=""
+
+DEPEND=""
+RDEPEND="
+	>=dev-vcs/git-2.7.4
+	dev-db/redis
+	virtual/ssh"
+ruby_add_bdepend "
+	virtual/ruby-ssl"
+
+MERGE_TYPE="binary"
+
+RUBY_PATCHES=(
+	"${PN}-3.2.0-config-paths.patch"
+)
+
+GIT_USER="git"
+DEST_DIR="/usr/share/${PN}"
+DATA_DIR="/var/lib/git"
+LOGS_DIR="/var/log/gitlab"
+CONF_FILE="/etc/gitlab-shell.yml"
+
+pkg_setup() {
+	enewgroup ${GIT_USER}
+	enewuser ${GIT_USER} -1 /bin/bash ${DATA_DIR} "${GIT_USER}"
+
+	local git_shell=$(egetshell ${GIT_USER})
+	if [ ! ${git_shell} -ef '/bin/bash' ]; then
+		ewarn "User ${GIT_USER} already exists, but with the shell ${git_shell}."
+		ewarn "Changing shell to /bin/bash ..."
+
+		usermod -s /bin/bash ${GIT_USER} \
+			|| die "failed to change login shell for ${GIT_USER}"
+	fi
+}
+
+all_ruby_prepare() {
+	# fix paths
+	sed -i -E \
+		-e "s|/home/git|${DATA_DIR}|" \
+		-e "s|[\# ]*(log_file: ).*|\1\"${LOGS_DIR}/gitlab-shell.log\"|" \
+		config.yml.example || die "failed to filter config.yml.example"
+
+	sed -i \
+		-e "s|File\.join(ROOT_PATH, 'config.yml')|'${CONF_FILE}'|" \
+		lib/gitlab_config.rb || die "failed to filter gitlab_config.rb"
+}
+
+all_ruby_install() {
+	# install lib
+	insinto ${DEST_DIR}; doins -r lib LICENSE README.md VERSION
+
+	# install scripts
+	exeinto ${DEST_DIR}/bin; doexe bin/*
+	exeinto ${DEST_DIR}/hooks; doexe hooks/*
+	exeinto ${DEST_DIR}/support; doexe support/*
+
+	# create symlinks to bin
+	local name; for name in $(basename -a bin/gitlab-*); do
+		dosym "${DEST_DIR}/bin/${name}" "/usr/bin/${name}"
+	done
+
+	insinto $(dirname ${CONF_FILE})
+	newins config.yml.example $(basename ${CONF_FILE})
+
+	# create symlink for .gitlab_shell_secret
+	einfo "creating symlink for .gitlab_shell_secret"
+	TOKEN_FILE="${DEST_DIR}/.gitlab_shell_secret"
+	dosym /opt/gitlab/.gitlab_shell_secret "$TOKEN_FILE"
+
+	# prepare directories
+	diropts -m750; dodir ${DATA_DIR}
+	diropts -m770; keepdir ${DATA_DIR}/repositories
+	diropts -m755; dodir ${LOGS_DIR}
+
+	# GitLab stupidly expects that gitlab-shell is in home of git user...
+	dosym ${DEST_DIR} ${DATA_DIR}/gitlab-shell
+
+	# fix permissions
+	fowners -R ${GIT_USER}:${GIT_USER} ${DATA_DIR} ${LOGS_DIR}
+}
+
+pkg_postinst() {
+	# check git home directory
+	local git_home=$(egethome ${GIT_USER})
+	if [ ! "${git_home}" -ef ${DATA_DIR} ]; then
+		ewarn "An authorized_keys is configured to be inside ${DATA_DIR}/.ssh,"
+		ewarn "but HOME of ${GIT_USER} user is located in ${git_home}. You must"
+		ewarn "either change the authorized_keys location in ${CONF_FILE},"
+		ewarn "or change home directory of ${GIT_USER} user to ${DATA_DIR}"
+		ewarn "and move ${git_home}/.ssh here."
+		ewarn
+	fi
+
+	local auth_dir="${git_home}/.ssh"
+
+	elog "Initializing authorized_keys file in ${auth_dir}"
+	mkdir -p ${auth_dir}
+	touch ${auth_dir}/authorized_keys
+	chmod -R u=rwX,go=- ${auth_dir}
+	chown -R ${GIT_USER}:${GIT_USER} ${auth_dir}
+
+	elog
+	elog "GitLab Shell was initialized. Repositories are located in"
+	elog "${DATA_DIR}/repositories, scripts in ${DEST_DIR}/bin."
+	elog "All gitlab-* scripts was symlinked to /usr/bin to be on your path."
+	elog
+	elog "You should change your gitlab_url in: ${CONF_FILE}."
+}
diff --git a/www-apps/gitlab-ce/gitlab-ce-8.12.3.ebuild b/www-apps/gitlab-ce/gitlab-ce-8.12.3.ebuild
new file mode 100644
index 0000000..c066a4a
--- /dev/null
+++ b/www-apps/gitlab-ce/gitlab-ce-8.12.3.ebuild
@@ -0,0 +1,386 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+# Maintainer notes:
+# - This ebuild uses Bundler to download and install all gems in deployment mode
+#   (i.e. into isolated directory inside application). That's not Gentoo way how
+#   it should be done, but GitLab has too many dependencies that it will be too
+#   difficult to maintain them via ebuilds.
+#
+
+USE_RUBY="ruby21 ruby23"
+
+inherit eutils ruby-ng user systemd
+
+MY_PV="v${PV/_/-}"
+MY_GIT_COMMIT="467e1ca48ebf6fe1614733e90e0396930f0a2eb9"
+
+DESCRIPTION="GitLab is a free project and repository management application"
+HOMEPAGE="https://about.gitlab.com/"
+SRC_URI="https://gitlab.com/gitlab-org/${PN}/repository/archive.tar.gz?ref=${MY_PV} -> ${P}.tar.gz"
+RUBY_S="${PN}-${MY_PV}-${MY_GIT_COMMIT}"
+
+RESTRICT="mirror"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~arm ~arm64"
+IUSE="kerberos mysql +postgres +unicorn systemd rugged_use_system_libraries"
+
+## Gems dependencies:
+#   charlock_holmes     dev-libs/icu
+#   grape, capybara     dev-libs/libxml2, dev-libs/libxslt
+#   rugged              dev-util/cmake, virtual/pkgconfig
+#   json                dev-util/ragel
+#   pygments.rb         python 2.7+
+#   execjs              net-libs/nodejs, or any other JS runtime
+#   pg                  dev-db/postgresql
+#   mysql               virtual/mysql
+#
+GEMS_DEPEND="
+	dev-libs/icu
+	dev-libs/libxml2
+	dev-libs/libxslt
+	dev-util/ragel
+	net-libs/nodejs
+	postgres? ( >=dev-db/postgresql-9.1:* )
+	mysql? ( virtual/mysql )
+	kerberos? ( virtual/krb5 )"
+CDEPEND="
+	dev-util/cmake
+	virtual/pkgconfig"
+COMMON_DEPEND="
+	${GEMS_DEPEND}
+	~dev-vcs/gitlab-shell-3.6.1
+	>=dev-vcs/git-2.7.4
+	~dev-vcs/gitlab-workhorse-0.8.2
+	kerberos? ( !app-crypt/heimdal )
+	rugged_use_system_libraries? ( net-libs/http-parser dev-libs/libgit2:0/24 )"
+DEPEND="
+	${CDEPEND}
+	${COMMON_DEPEND}"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=dev-db/redis-2.8
+	virtual/mta
+	systemd? ( sys-apps/systemd:0= )"
+ruby_add_bdepend "
+	virtual/rubygems
+	>=dev-ruby/bundler-1.0"
+
+#
+# fix-sendmail-config:
+#     Fix default settings to work with ssmtp that doesn't know '-t' argument.
+# fix-redis-config-path:
+#     Point to the absolute location of redis_config.rb
+#
+RUBY_PATCHES=(
+	"${PN}-8.7.5-fix-sendmail-config.patch"
+	"${PN}-8.11.0-fix-redis-config-path.patch"
+)
+
+MY_NAME="gitlab"
+MY_USER="git"    # should be same as in gitlab-shell
+
+DEST_DIR="/opt/${MY_NAME}"
+CONF_DIR="/etc/${MY_NAME}"
+LOGS_DIR="/var/log/${MY_NAME}"
+TEMP_DIR="/var/tmp/${MY_NAME}"
+
+# When updating ebuild to newer version, check list of the queues in
+# https://gitlab.com/gitlab-org/gitlab-ce/blob/${MY_PV}/bin/background_jobs
+SIDEKIQ_QUEUES="post_receive,mailers,archive_repo,system_hook,project_web_hook,gitlab_shell,incoming_email,runner,common,default"
+
+all_ruby_prepare() {
+	# fix paths
+	local satellites_path="${TEMP_DIR}/repo_satellites"
+	local repos_path=/var/lib/git/repositories
+	local shell_path=/usr/share/gitlab-shell
+	sed -i -E \
+		-e "/satellites:$/,/\w:$/   s|(\s*path:\s).*|\1${satellites_path}/|" \
+		-e "/gitlab_shell:$/,/\w:$/ s|(\s*path:\s).*|\1${shell_path}/|" \
+		-e "/gitlab_shell:$/,/\w:$/ s|(\s*repos_path:\s).*|\1${repos_path}/|" \
+		-e "/gitlab_shell:$/,/\w:$/ s|(\s*hooks_path:\s).*|\1${shell_path}/hooks/|" \
+		config/gitlab.yml.example || die "failed to filter gitlab.yml.example"
+
+	local run_path=/run/${MY_NAME}
+	sed -i -E \
+		-e "s|/home/git/gitlab/tmp/(pids\|sockets)|${run_path}|" \
+		-e "s|/home/git/gitlab/log|${LOGS_DIR}|" \
+		-e "s|/home/git/gitlab|${DEST_DIR}|" \
+		config/unicorn.rb.example || die "failed to filter unicorn.rb.example"
+
+	sed -i \
+		-e "s|/home/git/gitlab/tmp/sockets|${run_path}|" \
+		lib/support/nginx/gitlab || die "failed to filter nginx/gitlab"
+
+	# modify default database settings for PostgreSQL
+	sed -i -E \
+		-e 's|(username:).*|\1 gitlab|' \
+		-e 's|(password:).*|\1 gitlab|' \
+		-e 's|(socket:).*|\1 /run/postgresql/.s.PGSQL.5432|' \
+		config/database.yml.postgresql \
+		|| die "failed to filter database.yml.postgresql"
+
+	# rename config files
+	mv config/gitlab.yml.example config/gitlab.yml
+	mv config/unicorn.rb.example config/unicorn.rb
+
+	local dbconf=config/database.yml
+	if use postgres && ! use mysql; then
+		mv ${dbconf}.postgresql ${dbconf}
+		rm ${dbconf}.mysql
+	elif use mysql && ! use postgres; then
+		mv ${dbconf}.mysql ${dbconf}
+		rm ${dbconf}.postgresql
+	fi
+
+	# remove useless files
+	rm -r lib/support/{deploy,init.d}
+	use unicorn || rm config/unicorn.rb
+}
+
+all_ruby_install() {
+	local dest=${DEST_DIR}
+	local conf=${CONF_DIR}
+	local logs=${LOGS_DIR}
+	local temp=${TEMP_DIR}
+
+	# prepare directories
+	diropts -m750
+	dodir ${logs} ${temp}
+
+	diropts -m755
+	dodir ${conf} ${dest}/public/uploads
+
+	dosym ${temp} ${dest}/tmp
+	dosym ${logs} ${dest}/log
+
+	# install configs
+	insinto ${conf}
+	doins -r config/*
+	dosym ${conf} ${dest}/config
+
+	echo 'export RAILS_ENV=production' > "${D}/${dest}/.profile"
+
+	# remove needless dirs
+	rm -Rf config tmp log
+
+	# install the rest files
+	# using cp 'cause doins is slow
+	cp -Rl * "${D}/${dest}"/
+
+	# install logrotate config
+	dodir /etc/logrotate.d
+	cat > "${D}/etc/logrotate.d/${MY_NAME}" <<-EOF
+		${logs}/*.log {
+		    missingok
+		    delaycompress
+		    compress
+		    copytruncate
+		}
+	EOF
+
+	## Install gems via bundler ##
+
+	cd "${D}/${dest}"
+
+	local without="development test aws"
+	local flag; for flag in mysql postgres unicorn kerberos; do
+		without+="$(use $flag || echo ' '$flag)"
+	done
+	local bundle_args="--deployment ${without:+--without ${without}}"
+
+	use "rugged_use_system_libraries" && export RUGGED_USE_SYSTEM_LIBRARIES="YES"
+
+	einfo "Running bundle install ${bundle_args} ..."
+	${RUBY} /usr/bin/bundle install ${bundle_args} || die "bundler failed"
+
+	einfo "Cleaning old gems ..."
+	${RUBY} /usr/bin/bundle clean
+
+	# clean gems cache
+	rm -Rf vendor/bundle/ruby/*/cache
+	rm -Rf vendor/bundle/ruby/*/bundler/gems/charlock_holmes-dde194609b35/.git
+
+	## RC script ##
+
+	if use systemd ; then
+		ewarn "Beware: systemd support has not been tested, use at your own risk!"
+		systemd_newunit "${FILESDIR}/gitlab-8.10.6-sidekiq.service" "gitlab-sidekiq.service"
+		systemd_dounit "${FILESDIR}/gitlab-unicorn.service"
+		systemd_dounit "${FILESDIR}/gitlab-workhorse.service"
+		systemd_dounit "${FILESDIR}/gitlab-mailroom.service"
+		systemd_dotmpfilesd "${FILESDIR}/gitlab.conf"
+	else
+		local rcscript=gitlab-sidekiq.init
+		use unicorn && rcscript=gitlab-unicorn.init
+
+		cp "${FILESDIR}/${rcscript}" "${T}" || die
+		sed -i \
+			-e "s|@USER@|${MY_USER}|" \
+			-e "s|@GITLAB_BASE@|${dest}|" \
+			-e "s|@LOGS_DIR@|${logs}|" \
+			-e "s|@QUEUES@|${SIDEKIQ_QUEUES}|" \
+			"${T}/${rcscript}" \
+			|| die "failed to filter ${rcscript}"
+
+		newinitd "${T}/${rcscript}" "${MY_NAME}"
+	fi
+
+	# fix permissions
+	fowners -R ${MY_USER}:${MY_USER} ${dest} ${temp} ${logs}
+}
+
+pkg_postinst() {
+	elog "If this is an update from a previous version, stop your GitLab"
+	elog "instance and issue the following command to perform all required"
+	elog "migrations:"
+	elog "       emerge --config \"=${CATEGORY}/${PF}\""
+	elog "PLEASE NOTE: It's HIGHLY recommended to backup your database"
+	elog "before running the config phase. Run these commands (as root):"
+	elog
+	elog "    cd /opt/gitlab"
+	elog "    sudo -u git -H bundle exec rake gitlab:backup:create RAILS_ENV=production"
+	elog
+	elog "If this was a fresh install, follow these steps:"
+	elog
+	elog "1. Configure your GitLab's settings in ${CONF_DIR}/gitlab.yml."
+	elog
+	elog "2. Configure your database settings in ${CONF_DIR}/database.yml"
+	elog "   for \"production\" environment."
+	elog
+	elog "3. Then you should create a database for your GitLab instance, if you"
+	elog "   haven't done so already."
+	elog
+	if use postgres; then
+		elog "If you have local PostgreSQL running, just copy&run:"
+		elog "      su postgres"
+		elog "      psql -c \"CREATE ROLE gitlab PASSWORD 'gitlab' \\"
+		elog "          NOSUPERUSER NOCREATEDB NOCREATEROLE INHERIT LOGIN;\""
+		elog "      createdb -E UTF-8 -O gitlab gitlabhq_production"
+		elog "  Note: You should change your password to something more random..."
+		elog
+	fi
+	elog "4. Finally execute the following command to initialize the environment:"
+	elog "       emerge --config \"=${CATEGORY}/${PF}\""
+	elog "   Note: Do not forget to start Redis server first!"
+	elog
+	elog "If you're running GitLab behind an SSL proxy such as nginx or Apache and"
+	elog "you can't login after the upgrade, be sure to read the section about the"
+	elog "verification of the CSRF token in GitLab's trouble-shooting guide at"
+	elog "http://goo.gl/5XGRGv."
+	if use postgres; then
+		elog "Please note: As of GitLab 8.6, users of PostgreSQL need to enable the"
+		elog "`pg_trgm` extension by running the following command as a PostgreSQL"
+		elog "super user for *every* GitLab database:"
+		elog "      CREATE EXTENSION IF NOT EXISTS pg_trgm;"
+		elog "For details, see the documentation at the GitLab website."
+	fi
+}
+
+pkg_config() {
+	einfo "Checking configuration files"
+
+	if [ ! -r "${CONF_DIR}/database.yml" ]; then
+		eerror "Copy ${CONF_DIR}/database.yml.* to"
+		eerror "${CONF_DIR}/database.yml and edit this file in order to configure your"
+		eerror "database settings for \"production\" environment."; die
+	fi
+
+	local email_from="$(ryaml ${CONF_DIR}/gitlab.yml production gitlab email_from)"
+	local git_home="$(egethome ${MY_USER})"
+
+	# configure Git global settings
+	if [ ! -e "${git_home}/.gitconfig" ]; then
+		einfo "Setting git user"
+		su -l ${MY_USER} -c "
+			git config --global user.email '${email_from}';
+			git config --global user.name 'GitLab'" \
+			|| die "failed to setup git name and email"
+	fi
+
+	# determine whether this is an update or a fresh install. we do this by
+	# checking whether the ${DEST_DIR}/.git directory exists or not
+	# 
+	if [ -d "${DEST_DIR}/.git" ]; then
+		local update=true
+	else
+		local update=false
+	fi
+
+	## Initialize app ##
+
+	local RAILS_ENV="production"
+	local RUBY=${RUBY:-/usr/bin/ruby}
+	local BUNDLE="${RUBY} /usr/bin/bundle"
+
+	# FIXME: this line existed in older ebuilds, but the variable is
+	# never used. what was it for!?
+	# local dbname="$(ryaml ${CONF_DIR}/database.yml production database)"
+
+	if [ "${update}" = 'true' ]; then
+		einfo "Migrating database ..."
+		exec_rake db:migrate
+
+		# https://github.com/gitlabhq/gitlabhq/issues/5311#issuecomment-31656496
+		einfo "Migrating iids ..."
+		exec_rake migrate_iids
+
+		einfo "Cleaning old precompiled assets ..."
+		exec_rake assets:clean
+
+		einfo "Cleaning cache ..."
+		exec_rake cache:clear
+	else
+		# create dummy git repo as workaround for
+		# https://github.com/bundler/bundler/issues/2039
+		einfo "Initializing dummy git repository to avoid false errors from bundler"
+		su -l ${MY_USER} -c "
+			cd ${DEST_DIR}
+			git init
+			git add README.md
+			git commit -m 'Dummy repository'" >/dev/null
+
+		einfo "Initializing database ..."
+		exec_rake gitlab:setup
+	fi
+
+	einfo "Precompiling assests ..."
+	exec_rake assets:precompile
+
+	if [ "${update}" = 'true' ]; then
+		ewarn
+		ewarn "This configuration script runs only common migration tasks."
+		ewarn "Please read guides on"
+		ewarn "    https://github.com/gitlabhq/gitlabhq/blob/master/doc/update/"
+		ewarn "for any additional migration tasks specific to your previous GitLab"
+		ewarn "version."
+	fi
+	elog
+	elog "If you want to make sure that the install/upgrade was successful, start"
+	elog "Gitlab now and then run these commands (as root):"
+	elog
+	elog "    cd /opt/gitlab"
+	elog "    sudo -u git -H bundle exec rake gitlab:env:info RAILS_ENV=production"
+	elog "    sudo -u git -H bundle exec rake gitlab:check RAILS_ENV=production"
+	elog
+}
+
+ryaml() {
+	ruby -ryaml -e 'puts ARGV[1..-1].inject(YAML.load(File.read(ARGV[0]))) {|acc, key| acc[key] }' "$@"
+}
+
+exec_rake() {
+	local command="${BUNDLE} exec rake $@ RAILS_ENV=${RAILS_ENV}"
+
+	echo "   ${command}"
+	su -l ${MY_USER} -c "
+		export LANG=en_US.UTF-8; export LC_ALL=en_US.UTF-8
+		cd ${DEST_DIR}
+		${command}" \
+		|| die "failed to run rake $@"
+}