added ebuild for ekiga-3.0.1

net-im/ekiga/Manifest

@@ -0,0 +1,2 @@
+DIST ekiga-3.0.1.tar.bz2 7780111 RMD160 22868916a07842088c8c5351df103b5969a74137 SHA1 96c0dea54c58206c00bd193e6ab5924abc1acb67 SHA256 c440b85f370f31b82ee78a9d3258fcbab6107e56f549a48813d3190b2e3766c4
+EBUILD ekiga-3.0.1.ebuild 2689 RMD160 2fcfe596bd7258ef24867972ddd0eb432d77a90f SHA1 adc2088578864e7a6051f4d88f0344413d73ed2b SHA256 fa278dbc435c1caad8ce102754d0e461f57fe106afeb8a3cd850006b596f077a

net-im/ekiga/ekiga-3.0.1.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="1"
+
+inherit eutils gnome2
+
+DESCRIPTION="H.323 and SIP VoIP softphone"
+HOMEPAGE="http://www.ekiga.org/"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="avahi dbus debug doc eds gconf gnome ldap libnotify xv"
+
+RDEPEND=">=dev-libs/ptlib-2.4.2
+	>=net-libs/opal-3.4.2
+	>=x11-libs/gtk+-2.12.0:2
+	>=dev-libs/glib-2.8.0:2
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	avahi? ( >=net-dns/avahi-0.6.0 )
+	dbus? ( >=dev-libs/dbus-glib-0.36 )
+	eds? ( >=gnome-extra/evolution-data-server-1.2 )
+	gconf? ( >=gnome-base/gconf-2.6.0:2 )
+	gnome? ( >=gnome-base/libgnome-2.14.0
+		>=gnome-base/libgnomeui-2.14.0 )
+	ldap? ( net-nds/openldap )
+	libnotify? ( x11-libs/libnotify )
+	xv? ( x11-libs/libXv )"
+
+DEPEND="${RDEPEND}
+	>=sys-devel/make-3.81
+	>=dev-util/pkgconfig-0.12.0
+	>=dev-util/intltool-0.35
+	doc? ( app-text/scrollkeeper
+		app-text/gnome-doc-utils )"
+
+DOCS="AUTHORS ChangeLog FAQ NEWS README"
+
+pkg_setup() {
+	# ekiga has to be built like opal and ptlib but as opal has to be built
+	# like ptlib, it should be possible to check only opal but as ekiga is
+	# linking to both, we are cheking both
+	if use debug && (! built_with_use dev-libs/ptlib debug ||
+		! built_with_use net-libs/opal debug); then
+		eerror "You need to build dev-libs/ptlib and net-libs/opal with\
+ USE=debug enabled."
+		die "dev-libs/ptlib and net-libs/opal have to be built with USE=debug"
+	fi
+
+	if ! use debug && (built_with_use dev-libs/ptlib debug ||
+		built_with_use net-libs/opal debug); then
+		eerror "You need to build dev-libs/ptlib and net-libs/opal without\
+ USE=debug."
+		die "dev-libs/ptlib and net-libs/opal has not to be built with USE=debug"
+	fi
+
+	# dbus-service is always enable if dbus is enable, no reason to disable it
+	G2CONF="${G2CONF}
+		$(use_enable avahi)
+		$(use_enable dbus)
+		$(use_enable dbus dbus_service)
+		$(use_enable debug)
+		$(use_enable doc gdu)
+		$(use_enable eds)
+		$(use_enable gconf)
+		$(use_enable gnome)
+		$(use_enable ldap)
+		$(use_enable libnotify notify)
+		$(use_enable xv)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# remove call to gconftool-2 --shutdown
+	sed -i -e '/gconftool-2 --shutdown/d' Makefile.in \
+		|| die "Patching Makefile.in failed"
+
+	# fix ekiga-helper dbus service .in file
+	sed -i -e 's/@PACKAGE_NAME@/ekiga/'\
+		src/components/org.ekiga.Helper.service.in \
+		|| die "Patching src/components/org.ekiga.Helper.service.in failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+
+	if ! use gnome; then
+		ewarn "USE=-gnome is experimental, some weirdness with the UI and"
+		ewarn "config keys should appear."
+	fi
+}